Private Sub Main()
    Dim Buffer() As Byte
    Dim PlainText As String
    
    ' Create a new RC2CryptoServiceProvider key.
    Dim Key As New RC2CryptoServiceProvider

    ' Encrypt a string to a byte array.
    Buffer = Encrypt("This is some plaintext!", Key)
    Debug.Print "Encrypted data"
    PrintBytes Buffer
    Debug.Print
    
    ' Decrypt the byte array back to a string.
    PlainText = Decrypt(Buffer, Key)

    ' Display the plaintext value to the console.
    Debug.Print "Decrypted data"
    Debug.Print PlainText
End Sub

Private Sub PrintBytes(ByRef Bytes() As Byte)
    Dim i As Long
    
    For i = LBound(Bytes) To UBound(Bytes)
        Debug.Print Object.ToString(Bytes(i), "X2"); " ";
    Next
    
    Debug.Print
End Sub

' Encrypt the string.
Private Function Encrypt(ByVal PlainText As String, ByVal Key As SymmetricAlgorithm) As Byte()
    Dim Encryptor As ICryptoTransform
    Dim Buffer() As Byte
    
    Buffer = Encoding.UTF8.GetBytes(PlainText)
    Set Encryptor = Key.CreateEncryptor
    Encrypt = Encryptor.TransformFinalBlock(Buffer, 0, CorArray.Length(Buffer))
End Function


' Decrypt the byte array.
Public Function Decrypt(ByRef CypherText() As Byte, ByVal Key As SymmetricAlgorithm) As String
    Dim Decryptor As ICryptoTransform
    Dim Buffer() As Byte
        
    Set Decryptor = Key.CreateDecryptor
    Buffer = Decryptor.TransformFinalBlock(CypherText, 0, CorArray.Length(CypherText))
    Decrypt = Encoding.UTF8.GetString(Buffer)
End Function

' This example code produces the following output. (encrypted data may be different because key is random)
'
'    Encrypted Data
'    B3 70 EC 9E 4C 6F A1 43 CA 1E 64 68 95 E5 0C A0 E0 71 0B DA CB 09 B4 42
'
'    Decrypted Data
'    This is some plaintext!