Private Sub Main()
    Dim Key As New TripleDESCryptoServiceProvider
    Dim Buffer() As Byte
    Dim PlainText As String

    ' Encrypt a string to a byte array.
    Buffer = Encrypt("This is some plaintext!", Key)

    Debug.Print "Encrypted data"
    PrintBytes Buffer
    Debug.Print

    ' Decrypt the byte array back to a string.
    PlainText = Decrypt(Buffer, Key)

    ' Display the plaintext value to the console.
    Debug.Print "Original text"
    Debug.Print PlainText
End Sub

Private Sub PrintBytes(ByRef Bytes() As Byte)
    Dim i As Long
    
    For i = LBound(Bytes) To UBound(Bytes)
        Debug.Print Object.ToString(Bytes(i), "X2"); " ";
    Next
    
    Debug.Print
End Sub

' Encrypt the string.
Private Function Encrypt(ByVal PlainText As String, ByVal Key As SymmetricAlgorithm) As Byte()
    Dim Encryptor As ICryptoTransform
    Dim Buffer() As Byte
    
    Buffer = Encoding.UTF8.GetBytes(PlainText)
    Set Encryptor = Key.CreateEncryptor
    Encrypt = Encryptor.TransformFinalBlock(Buffer, 0, CorArray.Length(Buffer))
End Function

' Decrypt the byte array.
Public Function Decrypt(ByRef CypherText() As Byte, ByVal Key As SymmetricAlgorithm) As String
    Dim Decryptor As ICryptoTransform
    Dim Buffer() As Byte
    
    Set Decryptor = Key.CreateDecryptor
    Buffer = Decryptor.TransformFinalBlock(CypherText, 0, CorArray.Length(CypherText))
    Decrypt = Encoding.UTF8.GetString(Buffer)
End Function

' This example produces the following output.
'
'    Encrypted Data (may be different because key is generated)
'    41 40 45 31 BF D9 B5 9C 63 0E CB 0B 83 D8 DD 81 AA 47 5C F1 05 5D C2 04
'
'    Original Text
'    This is some plaintext!